Arduino Pro Mini má dva nezávislé spôsoby ovládania:
Mikrospínač: prepína medzi režimom stáleho svietenia a blikania.
RC prijímač: pomocou PWM signálu z vysielača zapína alebo vypína všetky LED.
RC ovládanie bude mať prednosť. Keď na vysielači LED vypnete, zhasnú bez ohľadu na zvolený režim. Keď ich zapnete, pokračujú v režime nastavenom mikrospínačom.
Zapojenie:
| Súčiastka | Arduino Pro Mini |
| Mikrospínač |
D2 a GND |
| Červená LED |
D3 |
| Zelená LED |
D4 |
| Biela LED 1 |
D5 |
| Biela LED 2 |
D6 |
| PWM signál z prijímača |
D7 |
| GND prijímača |
GND Arduina |
| +5V |
ACC |
Ovládanie v praxi:
| Ovládanie | Výsledok |
| RC prepínač OFF |
Všetky LED zhasnú |
| RC prepínač ON + mikrospínač režim 1 |
Stále svietenie |
| RC prepínač ON + mikrospínač režim 2 |
Blikanie |
| Strata RC signálu |
LED automaticky zhasnú |
Kód pro Arduino:
#include <EEPROM.h>
// Vstupy
const byte BUTTON_PIN = 2;
const byte RC_PIN = 7;
// Vystupy LED
const byte RED_LED = 3;
const byte GREEN_LED = 4;
const byte WHITE_LED1 = 5;
const byte WHITE_LED2 = 6;
// Rezimy
// 1 = stale svietenie
// 2 = blikanie
byte mode = 1;
// RC ovladanie
bool ledsEnabled = false;
unsigned long lastValidSignal = 0;
// Tlacidlo
bool lastButtonReading = HIGH;
bool stableButtonState = HIGH;
unsigned long lastDebounceTime = 0;
const unsigned long debounceDelay = 35;
// Blikanie
unsigned long lastFlashTime = 0;
void setup() {
pinMode(BUTTON_PIN, INPUT_PULLUP);
pinMode(RC_PIN, INPUT);
pinMode(RED_LED, OUTPUT);
pinMode(GREEN_LED, OUTPUT);
pinMode(WHITE_LED1, OUTPUT);
pinMode(WHITE_LED2, OUTPUT);
// Nacitanie posledneho rezimu
byte savedMode = EEPROM.read(0);
if (savedMode == 1 || savedMode == 2) {
mode = savedMode;
}
allOff();
}
void loop() {
readButton();
readRC();
// Pri strate RC signalu LED zhasnu
if (millis() - lastValidSignal > 100) {
ledsEnabled = false;
}
// RC ma prednost
if (!ledsEnabled) {
allOff();
return;
}
if (mode == 1) {
allOn();
}
else {
aircraftLights();
}
}
void readButton() {
bool reading = digitalRead(BUTTON_PIN);
if (reading != lastButtonReading) {
lastDebounceTime = millis();
}
if (millis() - lastDebounceTime > debounceDelay) {
if (reading != stableButtonState) {
stableButtonState = reading;
if (stableButtonState == LOW) {
mode++;
if (mode > 2) {
mode = 1;
}
EEPROM.update(0, mode);
lastFlashTime = millis();
}
}
}
lastButtonReading = reading;
}
void readRC() {
// Citame PWM signal s timeoutom 25 ms
unsigned long signal = pulseIn(RC_PIN, HIGH, 25000);
if (signal >= 900 & signal <= 2100) {
lastValidSignal = millis();
// Dvojpolohovy prepinac na vysielaci
if (signal > 1500) {
ledsEnabled = true;
}
else {
ledsEnabled = false;
}
}
}
void allOn() {
digitalWrite(RED_LED, HIGH);
digitalWrite(GREEN_LED, HIGH);
digitalWrite(WHITE_LED1, HIGH);
digitalWrite(WHITE_LED2, HIGH);
}
void allOff() {
digitalWrite(RED_LED, LOW);
digitalWrite(GREEN_LED, LOW);
digitalWrite(WHITE_LED1, LOW);
digitalWrite(WHITE_LED2, LOW);
}
void aircraftLights() {
unsigned long t = millis() - lastFlashTime;
// Pozičné svetlá
digitalWrite(RED_LED, HIGH);
digitalWrite(GREEN_LED, HIGH);
// Dva kratke biele zablesky
bool whiteFlash =
(t < 100) ||
(t >= 200 & t < 300);
digitalWrite(WHITE_LED1, whiteFlash);
digitalWrite(WHITE_LED2, whiteFlash);
// Cyklus 1 sekunda
if (t >= 1000) {
lastFlashTime = millis();
}
}